*  JieJie Microelectronics H-Spice Model Library
*  Filename	: JMH65R430AK_H v.20220622.txt
*  Product Name   : JMH65R430AK (TO-252-3L)
*  Configuration:	: Single N-channel Device
*  Data Sheet Rev.	: 1.0
*  Release Date	: Jun22, 2022
*  Junction Temp (Tj): -40C ~ 150C
******************************************************************************************************
*  This model is designed as a tool to assist end user(s) to evaluate the performance
*  of the particular SGT MOSFET (named above) released by JJMSH(R).  It has been
*  verified for function and timing integrity with the commercially available EDA simulat-
*  ion tools. End-user(s) is/are advised to take the best engineering practice (e.g.
*  bread-boarding, laboratory measurement) for the full evaluation.
*
*  Despite of the best effort on engineering & verification, JieJie Microelectronics Co.,
*  Ltd. ("JJM") does not provide any warranty nor take any liability to the results and
*  their effects whatsoever from the simulation run of this model by the end-user(s).
*  While this model may be updated at appropriate times in the future without prior
*  notice, JJM does not assume the sole responsibility for update. 
*
.subckt JMH65R430AK D G S 
M1 1 2 3 3 NMOS L=1E-006 W=1E-006
RD D 1 0.3
RS S 3 1E-006
RG G 2 8.5
CGS 3 G 7E-10
EGD 12 0 2 1 1
VFB 14 0 0
FFB 2 1 VFB 1
CGD 13 14 1E-9
DDG 15 14 DCGD
R2 12 15 1
D2 15 0 DLIM
DSD 3 D DSUB
RR 13 0 1
D1 12 13 DLIM
CDS D 3 POLY 2.45964E-9 -9.00146E-11 1.07046E-12 -5.65691E-15 1.46955E-17 -1.83799E-20 8.84123E-24

.model NMOS NMOS
+LEVEL = 3                     tlev = 1                      tlevc = 0   
+acm = 4                       VMAX = 5.980848E6             ETA = 1.241069E-4    
+VTO = 3.990168                TOX = 5.979588E-12            NSUB = 2.664003E19   
+KP = 9.9375                   U0 = 7.528208E-4              KAPPA = 4.34272E-2  
+GAMMA = 3.058823              PHI = 0.445456                THETA = -4.54521E-6  
+BEX = -0.72512                TCV = 1.824E-3                DELTA = 470.191002  

.model DCGD D
+CJO = 5.98E-10                VJ = 6                        M = 1.8  

.model DSUB D
+IS = 6.923642E-11             N = 1.624842                  RS = 1.129339E-4   
+BV = 675                      tlev = 0                      tlevc = 0   
+tref = -1.835005              eg = 1.407837                 keg = 4.843649   
+gap1 = 1.08738E-2             gap2 = 8.366377               xti = -3.788228E-3  
+cta = 0                       ctp = 0                       tcv = 0  
+tm1 = 0                       tm2 = 0                       tpb = 0   
+tphp = 0                      trs = 0                       ttt1 = 0   
+ttt2 = 0                      xtitun = 3   

.model DLIM D
+IS = 1E-4     
.ends JMH65R430AK

******************************************************************************************************
*  Copyright (C) 2021 JJM. All rights reserved.
******************************************************************************************************
